Excel应用程序对象(Application对象)及其常用方法基本操作应用示例
Application对象代表整个Microsoft Excel应用程序，带有175个属性和52个方法，可以设置整个应用程序的环境或配置应用程序。
示例01-01：体验开/关屏幕更新(ScreenUpdating属性)Sub 关闭屏幕更新()
MsgBox "顺序切换工作表Sheet1→Sheet2→Sheet3→Sheet2，先开启屏幕更新，然后关闭屏幕更新"
Worksheets(1).Select
MsgBox "目前屏幕中显示工作表Sheet1"
Application.ScreenUpdating = True
Worksheets(2).Select
MsgBox "显示Sheet2了吗？"
Worksheets(3).Select
MsgBox "显示Sheet3了吗？"
Worksheets(2).Select
MsgBox "下面与前面执行的程序代码相同,但关闭屏幕更新功能"
Worksheets(1).Select
MsgBox "目前屏幕中显示工作表Sheet1" & Chr(10) & "关屏屏幕更新功能"
Application.ScreenUpdating = False
Worksheets(2).Select
MsgBox "显示Sheet2了吗？"
Worksheets(3).Select
MsgBox "显示Sheet3了吗？"
Worksheets(2).Select
Application.ScreenUpdating = True
End Sub
示例说明：ScreenUpdating属性用来控制屏幕更新。当运行一个宏程序处理涉及到多个工作表或单元格中的大量数据时，若没有关闭屏幕更新，则会占用CPU的处理时间，从而降低程序的运行速度，而关闭该属性则可显著提高程序运行速度。
示例01-02：使用状态栏(StatusBar属性)Sub testStatusBar()
Application.DisplayStatusBar = True
'开启状态栏显示
'赋值状态栏显示的文本 Application.StatusBar = "
http://fanjy.blog.excelhome.net"
End Sub
示例说明：StatusBar属性用来指定显示在状态栏上的信息。若不想再显示状态栏文本，可使用
Application.StatusBar = False语句关闭状态栏显示，也可以在程序开始将原先的状态栏设置存储，如使用语句
oldStatusBar = Application.DisplayStatusBar将状态栏原来的信息存储在变量oldStatusBar，在程序运行完成或退出时，将变量重新赋值给状态栏，如使用语句
Application.DisplayStatusBar = oldStatusBar，以恢复状态栏原状。
示例01-03：处理光标(Cursor属性)Sub ViewCursors()
Application.Cursor = xlNorthwestArrow
MsgBox "您将使用箭头光标,切换到Excel界面查看光标形状"
Application.Cursor = xlIBeam
MsgBox "您将使用工形光标,切换到Excel界面查看光标形状"
Application.Cursor = xlWait
MsgBox "您将使用等待形光标,切换到Excel界面查看光标形状"
Application.Cursor = xlDefault
MsgBox "您已将光标恢复为缺省状态"
End Sub
示例01-04：获取系统信息Sub GetSystemInfo()
MsgBox "Excel版本信息为:" & Application.CalculationVersion
MsgBox "Excel当前允许使用的内存为:" & Application.MemoryFree
MsgBox "Excel当前已使用的内存为:" & Application.MemoryUsed
MsgBox "Excel可以使用的内存为:" & Application.MemoryTotal
MsgBox "本机操作系统的名称和版本为:" & Application.OperatingSystem
MsgBox "本产品所登记的组织名为:" & Application.OrganizationName
MsgBox "当前用户名为:" & Application.UserName
MsgBox "当前使用的Excel版本为:" & Application.Version
End Sub
示例说明：可以使用给UserName属性赋值以设置用户名称。
示例01-05：退出复制/剪切模式(CutCopyMode属性)Sub exitCutCopyMode()
Application.CutCopyMode = False
End Sub
示例说明：退出复制/剪切模式后，在程序运行时所进行的复制或剪切操作不会在原单元格区域留下流动的虚框线。需要提醒的是，在程序运行完后，应使用
Application.CutCopyMode = False语句恢复该属性的默认设置。
示例01-06：禁止弹出警告信息(DisplayAlerts属性)Sub testAlertsDisplay()
Application.DisplayAlerts = False
End Sub
示例说明：在程序运行过程中，有时由于Excel本身设置的原因，会弹出对话框，从而中断程序的运行，您可以在程序之前加上
Application.DisplayAlerts = False语句以禁止弹出这些对话框而不影响程序正常运行。需要注意的是，在程序运行结束前，应使DisplayAlerts属性恢复为缺省状态，即使用语句
Application.DisplayAlerts = True。该属性的默认设置为True，当将该属性设置为False时，Excel会使直接使用对话框中默认的选择，从而不会因为弹出对话框而影响程序运行。
示例01-07：将Excel全屏幕显示Sub testFullScreen()
MsgBox "运行后将Excel的显示模式设置为全屏幕"
Application.DisplayFullScreen = True
MsgBox "恢复为原来的状态"
Application.DisplayFullScreen = False
End Sub
示例01-08：Excel启动的文件夹路径
Sub ExcelStartfolder()
MsgBox "Excel启动的文件夹路径为：" & Chr(10) & Application.StartupPath
End Sub
示例01-09：打开最近使用过的文档Sub OpenRecentFiles()
MsgBox "显示最近使用过的第三个文件名,并打开该文件"
MsgBox "最近使用的第三个文件的名称为:" & Application.RecentFiles(3).Name
Application.RecentFiles(3).Open
End Sub
示例01-10：打开文件(FindFile方法)Sub FindFileOpen()
On Error Resume Next
MsgBox "请打开文件", vbOKOnly + vbInformation, "打开文件"
If Not Application.FindFile Then
MsgBox "文件未找到", vbOKOnly + vbInformation, "打开失败"
End If
End Sub
示例说明：本示例将显示“打开”文件对话框，若用户未打开文件(即点击“取消”按钮)，则会显示“打开失败”信息框。示例中使用了FindFile方法，用来显示“打开”对话框并让用户打开一个文件。如果成功打开一个新文件，则该值为True。如果用户取消了操作并退出该对话框，则该值为False。
示例01-11：文件对话框操作(FileDialog属性)Sub UseFileDialogOpen()
Dim lngCount As Long
'开启"打开文件"对话框
With Application.FileDialog(msoFileDialogOpen)
.AllowMultiSelect = True
.Show
'显示所选的每个文件的路径
For lngCount = 1 To .SelectedItems.Count
MsgBox .SelectedItems(lngCount)
Next lngCount
End With
End Sub
示例说明：本示例显示“打开文件”对话框，当用户在其中选择一个或多个文件后，将依次显示每个文件的路径。其中，FileDialog属性返回打开和保存对话框中一系列对象的集合，您可以对该集合对象的属性进行进一步的设置，如上例中的AllowMultiSelect属性设置为True将允许用户选择多个文件。
示例01-12：保存Excel的工作环境Sub 保存Excel的工作环境()
MsgBox "将Excel的工作环境保存到D:/ExcelSample/中"
Application.SaveWorkspace "D:/ExcelSample/Sample"
End Sub
示例说明：运行本程序后，将工作簿以带后缀名.xlw保存到D盘的ExcelSample文件夹中，生成的文件全名为Sample.xlw。当改变工作簿并保存时，Excel会询问是覆盖原文件还是保存副本。
示例01-13：改变Excel工作簿名字(Caption属性)Sub SetCaption()
Application.Caption = "My ExcelBook"
End Sub
示例说明：运行本程序后，将工作簿左上角Excel图标右侧的“Microsoft Excel”改为“My ExcelBook”。
示例01-14：使用InputBox方法Sub SampleInputBox()
Dim vInput
vInput = InputBox("请输入用户名:", "获取用户名", Application.UserName)
MsgBox "您好!" & vInput & ".很高兴能认识您.", vbOKOnly, "打招呼"
End Sub
示例01-15：设置页边距(CentimetersToPoints方法)Sub SetLeftMargin()
MsgBox "将工作表Sheet1的左页边距设为5厘米"
Worksheets("Sheet1").PageSetup.LeftMargin = Application.CentimetersToPoints(5)
End Sub
示例01-16：使用Windows的计算器(ActivateMicrosoftApp方法)Sub CallCalculate()
Application.ActivateMicrosoftApp Index:=0
End Sub
示例说明：运行本程序后，将调用Windows的计算器。
示例01-17：在程序中运行另一个宏(Run方法)Sub runOtherMacro()
MsgBox "本程序先选择A1至C6单元格区域后执行DrawLine宏"
ActiveSheet.Range("A2:C6").Select
Application.Run "DrawLine"
End Sub
示例01-18：在指定的时间执行宏(OnTime方法)Sub AfterTimetoRun()
MsgBox "从现在开始,10秒后执行程序「testFullScreen」"
Application.OnTime Now + TimeValue("00:00:10"), "testFullScreen"
End Sub
示例说明：运行本程序后，在10秒后将执行程序testFullScreen。
示例01-19：暂时停止宏运行(Wait方法)Sub Stop5sMacroRun()
Dim SetTime As Date
MsgBox "按下「确定」,5秒后执行程序「testFullScreen」"
SetTime = DateAdd("s", 5, Now())
Application.Wait SetTime
Call testFullScreen
End Sub
示例说明：运行本程序后，按下弹出的提示框中的“确定”按钮，等待5秒后执行另一程序testFullScreen。
示例01-20：按下指定的按键后执行程序(OnKey方法)[示例01-20-1]
Sub PressKeytoRun()
MsgBox "按下Ctrl+D后将执行程序「testFullScreen」"
Application.OnKey "^{d}", "testFullScreen"
End Sub
[示例01-20-2]
Sub ResetKey()
MsgBox "恢复原来的按键状态"
Application.OnKey "^{d}"
End Sub
示例说明：Onkey方法的作用主要是指定特定的键，当按下指定的键时运行相应的宏程序，或者按下指定的键时，使Excel屏蔽特定的功能。
示例01-21：重新计算工作簿[示例01-21-1]
Sub CalculateAllWorkbook()
Application.Calculate
End Sub
示例说明：当工作簿的计算模式被设置为手动模式后，运用Calculate方法可以重新计算所有打开的工作簿、工作簿中特定的工作表或者工作表中指定的单元格区域。
[示例01-21-2]
Sub CalculateFullSample()
If Application.CalculationVersion <> Workbooks(1).CalculationVersion Then
Application.CalculateFull
End If
End Sub
示例说明：本示例先将当前Microsoft Excel的版本与上次计算该工作簿的Excel版本进行比较，如果两个版本不同，则对所有打开工作簿中的数据进行一次完整计算。其中，CalculationVersion属性返回工作簿的版本信息。
示例01-22：控制函数重新计算(Volatile方法)Function NonStaticRand()
'当工作表中任意单元格重新计算时本函数更新
Application.Volatile True
NonStaticRand = Rnd()
End Function
示例说明：本示例摸仿Excel中的Rand()函数，当工作表单元格发生变化时，都会重新计算该函数。在例子中，使用了Volatile方法，强制函数进行重新计算，即无论何时重新计算工作表，该函数都会重新计算。
示例01-23：利用工作表函数(WorksheetFunction属性)Sub WorksheetFunctionSample()
Dim myRange As Range, answer
Set myRange = Worksheets("Sheet1").Range("A1:C10")
answer = Application.WorksheetFunction.Min(myRange)
MsgBox answer
End Sub
示例说明：本示例获取工作表Sheet1中单元格区域A1:C10中的最小值，使用了工作表函数Min()。一般，使用WorksheetFunction属性引用工作表函数，但如果VBA自带有实现相同功能的函数，则直接使用该函数，否则会出现错误。
示例01-24：获取重叠区域(Intersect方法)Sub IntersectRange()
Dim rSect As Range
Worksheets("Sheet1").Activate
Set rSect = Application.Intersect(Range("rg1"), Range("rg2"))
If rSect Is Nothing Then
MsgBox "没有交叉区域"
Else
rSect.Select
End If
End Sub
示例说明：本示例在工作表Sheet1中选定两个命名区域rg1和rg2的重叠区域，如果所选区域不重叠，则显示一条相应的信息。其中，Intersect方法返回一个Range对象，代表两个或多个范围重叠的矩形区域。
示例01-25：获取路径分隔符(PathSeparator属性)Sub GetPathSeparator()
MsgBox "路径分隔符为" & Application.PathSeparator
End Sub
示例说明：本示例使用PathSeparator属性返回路径分隔符(“/”)。
示例01-26：快速移至指定位置(Goto方法)Sub GotoSample()
Application.Goto Reference:=Worksheets("Sheet1").Range("A154"), _
scroll:=True
End Sub
示例说明：本示例运行后，将当前单元格移至工作表Sheet1中的单元格A154。
示例01-27：显示内置对话框(Dialogs属性)Sub DialogSample()
Application.Dialogs(xlDialogOpen).Show
End Sub
示例说明：本示例显示Excel的“打开”文件对话框。其中，Dialogs属性返回的集合代表所有的Excel内置对话框。
示例01-28：退出Excel(SendKeys方法)Sub SendKeysSample()
Application.SendKeys ("%fx")
End Sub
示例说明：本示例使用SendKeys方法退出Excel，若未保存，则会弹出提示对话框并让用户作出相应的选择。SendKeys方法的作用是摸拟键盘输入，如例中的“%fx”表示在Excel中同时按下Alt、F和X三个键。
示例01-29：关闭ExcelSub 关闭Excel()
MsgBox "Excel将会关闭"
Application.Quit
End Sub
示例说明：运行本程序后，若该工作簿未保存，则会弹出对话框询问是否保存。
=============================
